Initial commit retro music app

2018-07-27 18:37:33 +05:30 · 2018-07-27 18:37:33 +05:30 · fe890632fd
commit fe890632fd
parent ab332473bc
932 changed files with 83126 additions and 0 deletions
--- a/app/build.gradle
+++ b/app/build.gradle
@ -0,0 +1,145 @@
+apply plugin: 'com.android.application'
+
+android {
+    compileSdkVersion 28
+    buildToolsVersion '28.0.1'
+    defaultConfig {
+        minSdkVersion 21
+        targetSdkVersion 28
+
+        renderscriptTargetApi 28 //must match target sdk and build tools
+        vectorDrawables.useSupportLibrary = true
+
+        applicationId "code.name.monkey.retromusic"
+        versionCode 203
+        versionName 'R - 1.6.400'
+
+        multiDexEnabled true
+
+        buildConfigField("String", "LASTFM_API_KEY", "\"${getProperty(getProperties('../public.properties'), 'LASTFM_API_KEY')}\"")
+        buildConfigField("String", "GOOGLE_PLAY_LICENSE_KEY", "\"${getProperty(getProperties('../public.properties'), 'GOOGLE_PLAY_LICENSE_KEY')}\"")
+    }
+
+    buildTypes {
+        release {
+            minifyEnabled true
+            shrinkResources true
+            zipAlignEnabled true
+            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
+
+            resValue "string", "cast_app_id", "D3C555E1"
+        }
+        debug {
+            applicationIdSuffix '.debug'
+            versionNameSuffix ' DEBUG'
+
+            resValue "string", "cast_app_id", "D3C555E1"
+        }
+    }
+    flavorDimensions "default"
+    productFlavors {
+        normal {
+            versionCode defaultConfig.versionCode + 10000
+            versionName defaultConfig.versionName + "_" + getDate()
+            dimension "default"
+        }
+    }
+
+    packagingOptions {
+        exclude 'META-INF/LICENSE'
+        exclude 'META-INF/NOTICE'
+        exclude 'META-INF/rxjava.properties'
+    }
+    lintOptions {
+        disable 'MissingTranslation'
+        disable 'InvalidPackage'
+        abortOnError false
+    }
+    compileOptions {
+        sourceCompatibility JavaVersion.VERSION_1_8
+        targetCompatibility JavaVersion.VERSION_1_8
+    }
+    configurations.all {
+        resolutionStrategy.force 'com.google.code.findbugs:jsr305:1.3.9'
+    }
+
+    configurations.all {
+        resolutionStrategy.eachDependency { DependencyResolveDetails details ->
+            def requested = details.requested
+            if (requested.group == 'com.android.support') {
+                if (!requested.name.startsWith("multidex")) {
+                    details.useVersion '27.1.1'
+                }
+            }
+        }
+    }
+}
+
+def getProperties(String fileName) {
+    final def Properties properties = new Properties()
+    def file = file(fileName)
+    if (file.exists()) {
+        file.withInputStream { stream -> properties.load(stream) }
+    }
+    return properties
+}
+
+static def getProperty(Properties properties, String name) {
+    return properties.getProperty(name) ?: "$name missing"
+}
+
+static def getDate() {
+    new Date().format('yyyyMMdd')
+}
+
+ext {
+    supportLibVersion = "27.1.1"
+    firebase = "11.8.0"
+    retrofit = "2.3.0"
+    butterKnife = "8.8.1"
+    materialDialog = "0.9.6.0"
+}
+dependencies {
+    implementation fileTree(include: ['*.jar'], dir: 'libs')
+    implementation 'com.android.support:multidex:1.0.3'
+    implementation "com.android.support:appcompat-v7:$supportLibVersion"
+    implementation "com.android.support:recyclerview-v7:$supportLibVersion"
+    implementation "com.android.support:gridlayout-v7:$supportLibVersion"
+    implementation "com.android.support:cardview-v7:$supportLibVersion"
+    implementation "com.android.support:palette-v7:$supportLibVersion"
+    implementation "com.android.support:design:$supportLibVersion"
+    implementation "com.android.support:support-annotations:$supportLibVersion"
+    implementation "com.android.support:preference-v7:$supportLibVersion"
+    implementation "com.android.support:preference-v14:$supportLibVersion"
+    implementation "com.squareup.retrofit2:retrofit:$retrofit"
+    implementation "com.squareup.retrofit2:converter-gson:$retrofit"
+    implementation "com.squareup.retrofit2:adapter-rxjava2:$retrofit"
+    implementation "com.jakewharton:butterknife:$butterKnife"
+    annotationProcessor "com.jakewharton:butterknife-compiler:$butterKnife"
+    implementation "com.afollestad.material-dialogs:core:$materialDialog"
+    implementation "com.afollestad.material-dialogs:commons:$materialDialog"
+    implementation 'com.afollestad:material-cab:0.1.12'
+    implementation 'io.reactivex.rxjava2:rxandroid:2.0.2'
+    implementation 'io.reactivex.rxjava2:rxjava:2.1.9'
+    implementation 'com.github.bumptech.glide:glide:3.8.0'
+    implementation 'com.squareup.okhttp3:logging-interceptor:3.10.0'
+    implementation 'com.squareup.okhttp3:okhttp:3.10.0'
+    implementation 'com.github.bumptech.glide:okhttp3-integration:1.5.0'
+    implementation('com.h6ah4i.android.widget.advrecyclerview:advrecyclerview:0.11.0@aar') {
+        transitive = true
+    }
+    implementation 'com.mpatric:mp3agic:0.8.3'
+    implementation 'com.github.ksoichiro:android-observablescrollview:1.6.0'
+    implementation 'com.github.kabouzeid:RecyclerView-FastScroll:1.0.16-kmod'
+    implementation 'com.anjlab.android.iab.v3:library:1.0.44'
+    implementation 'jp.wasabeef:glide-transformations:2.0.2'
+    /*UI Library*/
+    implementation 'com.github.jetradarmobile:android-snowfall:1.1.6'
+    implementation 'uk.co.chrisjenx:calligraphy:2.3.0'
+    implementation 'me.zhanghai.android.materialprogressbar:library:1.4.2'
+    implementation 'com.r0adkll:slidableactivity:2.0.6'
+    /*Backend all*/
+    implementation project(':appthemehelper')
+    implementation 'com.sothree.slidinguppanel:library:3.4.0'
+    implementation 'org.nanohttpd:nanohttpd:2.3.1'
+}