mirror of
https://gitlab.gnome.org/jwestman/blueprint-compiler.git
synced 2025-05-05 16:09:07 -04:00
54164305a3
pygobject 3.52 has switched [1] to using libgirepository-2.0 which comes from glib itself now, rather than the 1.0 which came from gobject-introspection. This means that it fails to load the incompatible "GIRepository 2.0" and thus must be ported to 3.0 (which is provided by libgirepository-2.0). This also means that we have to bump the minimum version of glib to 2.80 Migration guide is here [2] [1]: https://gitlab.gnome.org/GNOME/pygobject/-/merge_requests/320 [2]: https://docs.gtk.org/girepository/migrating-gi.html
48 lines
1.2 KiB
Meson
48 lines
1.2 KiB
Meson
project('blueprint-compiler',
|
|
version: '0.14.0',
|
|
)
|
|
|
|
prefix = get_option('prefix')
|
|
datadir = join_paths(prefix, get_option('datadir'))
|
|
|
|
py = import('python').find_installation('python3')
|
|
|
|
dependency('glib-2.0', version: '>= 2.80.0')
|
|
dependency('girepository-2.0', version: '>= 2.80.0')
|
|
|
|
subdir('docs')
|
|
|
|
configure_file(
|
|
input: 'blueprint-compiler.pc.in',
|
|
output: 'blueprint-compiler.pc',
|
|
configuration: { 'VERSION': meson.project_version() },
|
|
install: not meson.is_subproject(),
|
|
install_dir: join_paths(datadir, 'pkgconfig'),
|
|
)
|
|
|
|
config = configuration_data({
|
|
'VERSION': meson.project_version(),
|
|
'LIBDIR': get_option('prefix') / get_option('libdir'),
|
|
})
|
|
|
|
if meson.is_subproject()
|
|
config.set('MODULE_PATH', meson.current_source_dir())
|
|
else
|
|
config.set('MODULE_PATH', py.get_install_dir())
|
|
endif
|
|
|
|
blueprint_compiler = configure_file(
|
|
input: 'blueprint-compiler.py',
|
|
output: 'blueprint-compiler',
|
|
configuration: config,
|
|
install: not meson.is_subproject(),
|
|
install_dir: get_option('bindir'),
|
|
)
|
|
|
|
if meson.is_subproject()
|
|
meson.override_find_program('blueprint-compiler', blueprint_compiler)
|
|
else
|
|
install_subdir('blueprintcompiler', install_dir: py.get_install_dir())
|
|
endif
|
|
|
|
subdir('tests')
|