rofi, fish

dot_config/private_fish/functions/__bass.py

@@ -0,0 +1,138 @@
+"""
+To be used with a companion fish function like this:
+
+        function refish
+            set -l _x (python /tmp/bass.py source ~/.nvm/nvim.sh ';' nvm use iojs); source $_x; and rm -f $_x
+        end
+
+"""
+
+from __future__ import print_function
+
+import json
+import os
+import signal
+import subprocess
+import sys
+import traceback
+
+
+BASH = 'bash'
+
+FISH_READONLY = [
+    'PWD', 'SHLVL', 'history', 'pipestatus', 'status', 'version',
+    'FISH_VERSION', 'fish_pid', 'hostname', '_', 'fish_private_mode'
+]
+
+IGNORED = [
+ 'PS1', 'XPC_SERVICE_NAME'
+]
+
+def ignored(name):
+    if name == 'PWD':  # this is read only, but has special handling
+        return False
+    # ignore other read only variables
+    if name in FISH_READONLY:
+        return True
+    if name in IGNORED or name.startswith("BASH_FUNC"):
+        return True
+    return False
+
+def escape(string):
+    # use json.dumps to reliably escape quotes and backslashes
+    return json.dumps(string).replace(r'$', r'\$')
+
+def escape_identifier(word):
+    return escape(word.replace('?', '\\?'))
+
+def comment(string):
+    return '\n'.join(['# ' + line for line in string.split('\n')])
+
+def gen_script():
+    # Use the following instead of /usr/bin/env to read environment so we can
+    # deal with multi-line environment variables (and other odd cases).
+    env_reader = "%s -c 'import os,json; print(json.dumps({k:v for k,v in os.environ.items()}))'" % (sys.executable)
+    args = [BASH, '-c', env_reader]
+    output = subprocess.check_output(args, universal_newlines=True)
+    old_env = output.strip()
+
+    pipe_r, pipe_w = os.pipe()
+    if sys.version_info >= (3, 4):
+      os.set_inheritable(pipe_w, True)
+    command = 'eval $1 && ({}; alias) >&{}'.format(
+        env_reader,
+        pipe_w
+    )
+    args = [BASH, '-c', command, 'bass', ' '.join(sys.argv[1:])]
+    p = subprocess.Popen(args, universal_newlines=True, close_fds=False)
+    os.close(pipe_w)
+    with os.fdopen(pipe_r) as f:
+        new_env = f.readline()
+        alias_str = f.read()
+    if p.wait() != 0:
+        raise subprocess.CalledProcessError(
+            returncode=p.returncode,
+            cmd=' '.join(sys.argv[1:]),
+            output=new_env + alias_str
+        )
+    new_env = new_env.strip()
+
+    old_env = json.loads(old_env)
+    new_env = json.loads(new_env)
+
+    script_lines = []
+
+    for k, v in new_env.items():
+        if ignored(k):
+            continue
+        v1 = old_env.get(k)
+        if not v1:
+            script_lines.append(comment('adding %s=%s' % (k, v)))
+        elif v1 != v:
+            script_lines.append(comment('updating %s=%s -> %s' % (k, v1, v)))
+            # process special variables
+            if k == 'PWD':
+                script_lines.append('cd %s' % escape(v))
+                continue
+        else:
+            continue
+        if k == 'PATH':
+            value = ' '.join([escape(directory)
+                              for directory in v.split(':')])
+        else:
+            value = escape(v)
+        script_lines.append('set -g -x %s %s' % (k, value))
+
+    for var in set(old_env.keys()) - set(new_env.keys()):
+        script_lines.append(comment('removing %s' % var))
+        script_lines.append('set -e %s' % var)
+
+    script = '\n'.join(script_lines)
+
+    alias_lines = []
+    for line in alias_str.splitlines():
+        _, rest = line.split(None, 1)
+        k, v = rest.split("=", 1)
+        alias_lines.append("alias " + escape_identifier(k) + "=" + v)
+    alias = '\n'.join(alias_lines)
+
+    return script + '\n' + alias
+
+script_file = os.fdopen(3, 'w')
+
+if not sys.argv[1:]:
+    print('__bass_usage', file=script_file, end='')
+    sys.exit(0)
+
+try:
+    script = gen_script()
+except subprocess.CalledProcessError as e:
+    sys.exit(e.returncode)
+except Exception:
+    print('Bass internal error!', file=sys.stderr)
+    raise # traceback will output to stderr
+except KeyboardInterrupt:
+    signal.signal(signal.SIGINT, signal.SIG_DFL)
+    os.kill(os.getpid(), signal.SIGINT)
+else:
+    script_file.write(script)

dot_config/private_fish/functions/_fzf_configure_bindings_help.fish

@@ -0,0 +1,43 @@
+function _fzf_configure_bindings_help --description "Prints the help message for fzf_configure_bindings."
+    echo "\
+USAGE:
+    fzf_configure_bindings [--COMMAND=[KEY_SEQUENCE]...]
+
+DESCRIPTION
+    fzf_configure_bindings installs key bindings for fzf.fish's commands and erases any bindings it
+    previously installed. It installs bindings for both default and insert modes. fzf.fish executes
+    it without options on fish startup to install the out-of-the-box key bindings.
+
+    By default, commands are bound to a mnemonic key sequence, shown below. Each command's binding
+    can be configured using a namesake corresponding option:
+        COMMAND            |  DEFAULT KEY SEQUENCE         |  CORRESPONDING OPTION
+        Search Directory   |  Ctrl+Alt+F (F for file)      |  --directory
+        Search Git Log     |  Ctrl+Alt+L (L for log)       |  --git_log
+        Search Git Status  |  Ctrl+Alt+S (S for status)    |  --git_status
+        Search History     |  Ctrl+R     (R for reverse)   |  --history
+        Search Processes   |  Ctrl+Alt+P (P for process)   |  --processes
+        Search Variables   |  Ctrl+V     (V for variable)  |  --variables
+    Override a command's binding by specifying its corresponding option with the desired key
+    sequence. Disable a command's binding by specifying its corresponding option with no value.
+
+    Because fzf_configure_bindings erases bindings it previously installed, it can be cleanly
+    executed multiple times. Once the desired fzf_configure_bindings command has been found, add it
+    to your config.fish in order to persist the customized bindings.
+
+    In terms of validation, fzf_configure_bindings fails if passed unknown options. It expects an
+    equals sign between an option's name and value. However, it does not validate key sequences.
+
+    Pass -h or --help to print this help message and exit.
+
+EXAMPLES
+    Default bindings but bind Search Directory to Ctrl+F and Search Variables to Ctrl+Alt+V
+        \$ fzf_configure_bindings --directory=\cf --variables=\e\cv
+    Default bindings but disable Search History
+        \$ fzf_configure_bindings --history=
+    An agglomeration of different options
+        \$ fzf_configure_bindings --git_status=\cg --history=\ch --variables= --processes=
+
+SEE Also
+    To learn more about fish key bindings, see bind(1) and fish_key_reader(1).
+"
+end

dot_config/private_fish/functions/_fzf_extract_var_info.fish

@@ -0,0 +1,15 @@
+# helper function for _fzf_search_variables
+function _fzf_extract_var_info --argument-names variable_name set_show_output --description "Extract and reformat lines pertaining to \$variable_name from \$set_show_output."
+    # Extract only the lines about the variable, all of which begin with either
+    # $variable_name: ...or... $variable_name[
+    string match --regex "^\\\$$variable_name(?::|\[).*" <$set_show_output |
+
+        # Strip the variable name prefix, including ": " for scope info lines
+        string replace --regex "^\\\$$variable_name(?:: )?" '' |
+
+        # Distill the lines of values, replacing...
+        #   [1]: |value|
+        # ...with...
+        #   [1] value
+        string replace --regex ": \|(.*)\|" ' $1'
+end

dot_config/private_fish/functions/_fzf_preview_changed_file.fish

@@ -0,0 +1,49 @@
+# helper for _fzf_search_git_status
+# arg should be a line from git status --short, e.g.
+# MM functions/_fzf_preview_changed_file.fish
+#  D README.md
+# R  LICENSE -> "New License"
+function _fzf_preview_changed_file --argument-names path_status --description "Show the git diff of the given file."
+    # remove quotes because they'll be interpreted literally by git diff
+    # no need to requote when referencing $path because fish does not perform word splitting
+    # https://fishshell.com/docs/current/fish_for_bash_users.html
+    set -l path (string unescape (string sub --start 4 $path_status))
+    # first letter of short format shows index, second letter shows working tree
+    # https://git-scm.com/docs/git-status/2.35.0#_short_format
+    set -l index_status (string sub --length 1 $path_status)
+    set -l working_tree_status (string sub --start 2 --length 1 $path_status)
+
+    set diff_opts --color=always
+
+    if test $index_status = '?'
+        _fzf_report_diff_type Untracked
+        _fzf_preview_file $path
+    else if contains {$index_status}$working_tree_status DD AU UD UA DU AA UU
+        # Unmerged statuses taken directly from git status help's short format table
+        # Unmerged statuses are mutually exclusive with other statuses, so if we see
+        # these, then safe to assume the path is unmerged
+        _fzf_report_diff_type Unmerged
+        git diff $diff_opts -- $path
+    else
+        if test $index_status != ' '
+            _fzf_report_diff_type Staged
+
+            # renames are only detected in the index, never working tree, so only need to test for it here
+            # https://stackoverflow.com/questions/73954214
+            if test $index_status = R
+                # diff the post-rename path with the original path, otherwise the diff will show the entire file as being added
+                set orig_and_new_path (string split --max 1 -- ' -> ' $path)
+                git diff --staged $diff_opts -- $orig_and_new_path[1] $orig_and_new_path[2]
+                # path currently has the form of "original -> current", so we need to correct it before it's used below
+                set path $orig_and_new_path[2]
+            else
+                git diff --staged $diff_opts -- $path
+            end
+        end
+
+        if test $working_tree_status != ' '
+            _fzf_report_diff_type Unstaged
+            git diff $diff_opts -- $path
+        end
+    end
+end

dot_config/private_fish/functions/_fzf_preview_file.fish

@@ -0,0 +1,43 @@
+# helper function for _fzf_search_directory and _fzf_search_git_status
+function _fzf_preview_file --description "Print a preview for the given file based on its file type."
+    # because there's no way to guarantee that _fzf_search_directory passes the path to _fzf_preview_file
+    # as one argument, we collect all the arguments into one single variable and treat that as the path
+    set file_path $argv
+
+    if test -L "$file_path" # symlink
+        # notify user and recurse on the target of the symlink, which can be any of these file types
+        set -l target_path (realpath "$file_path")
+
+        set_color yellow
+        echo "'$file_path' is a symlink to '$target_path'."
+        set_color normal
+
+        _fzf_preview_file "$target_path"
+    else if test -f "$file_path" # regular file
+        if set --query fzf_preview_file_cmd
+            # need to escape quotes to make sure eval receives file_path as a single arg
+            eval "$fzf_preview_file_cmd '$file_path'"
+        else
+            bat --style=numbers --color=always "$file_path"
+        end
+    else if test -d "$file_path" # directory
+        if set --query fzf_preview_dir_cmd
+            # see above
+            eval "$fzf_preview_dir_cmd '$file_path'"
+        else
+            # -A list hidden files as well, except for . and ..
+            # -F helps classify files by appending symbols after the file name
+            command ls -A -F "$file_path"
+        end
+    else if test -c "$file_path"
+        _fzf_report_file_type "$file_path" "character device file"
+    else if test -b "$file_path"
+        _fzf_report_file_type "$file_path" "block device file"
+    else if test -S "$file_path"
+        _fzf_report_file_type "$file_path" socket
+    else if test -p "$file_path"
+        _fzf_report_file_type "$file_path" "named pipe"
+    else
+        echo "$file_path doesn't exist." >&2
+    end
+end

dot_config/private_fish/functions/_fzf_report_diff_type.fish

@@ -0,0 +1,18 @@
+# helper for _fzf_preview_changed_file
+# prints out something like
+# ╭────────╮
+# │ Staged │
+# ╰────────╯
+function _fzf_report_diff_type --argument-names diff_type --description "Print a distinct colored header meant to preface a git patch."
+    # number of "-" to draw is the length of the string to box + 2 for padding
+    set repeat_count (math 2 + (string length $diff_type))
+    set line (string repeat --count $repeat_count ─)
+    set top_border ╭$line╮
+    set btm_border ╰$line╯
+
+    set_color yellow
+    echo $top_border
+    echo "│ $diff_type │"
+    echo $btm_border
+    set_color normal
+end

dot_config/private_fish/functions/_fzf_report_file_type.fish

@@ -0,0 +1,6 @@
+# helper function for _fzf_preview_file
+function _fzf_report_file_type --argument-names file_path file_type --description "Explain the file type for a file."
+    set_color red
+    echo "Cannot preview '$file_path': it is a $file_type."
+    set_color normal
+end

dot_config/private_fish/functions/_fzf_search_directory.fish

@@ -0,0 +1,34 @@
+function _fzf_search_directory --description "Search the current directory. Replace the current token with the selected file paths."
+    # Directly use fd binary to avoid output buffering delay caused by a fd alias, if any.
+    # Debian-based distros install fd as fdfind and the fd package is something else, so
+    # check for fdfind first. Fall back to "fd" for a clear error message.
+    set fd_cmd (command -v fdfind || command -v fd  || echo "fd")
+    set --append fd_cmd --color=always $fzf_fd_opts
+
+    # $fzf_dir_opts is the deprecated version of $fzf_directory_opts
+    set fzf_arguments --multi --ansi $fzf_dir_opts $fzf_directory_opts
+    set token (commandline --current-token)
+    # expand any variables or leading tilde (~) in the token
+    set expanded_token (eval echo -- $token)
+    # unescape token because it's already quoted so backslashes will mess up the path
+    set unescaped_exp_token (string unescape -- $expanded_token)
+
+    # If the current token is a directory and has a trailing slash,
+    # then use it as fd's base directory.
+    if string match --quiet -- "*/" $unescaped_exp_token && test -d "$unescaped_exp_token"
+        set --append fd_cmd --base-directory=$unescaped_exp_token
+        # use the directory name as fzf's prompt to indicate the search is limited to that directory
+        set --prepend fzf_arguments --prompt="Search Directory $unescaped_exp_token> " --preview="_fzf_preview_file $expanded_token{}"
+        set file_paths_selected $unescaped_exp_token($fd_cmd 2>/dev/null | _fzf_wrapper $fzf_arguments)
+    else
+        set --prepend fzf_arguments --prompt="Search Directory> " --query="$unescaped_exp_token" --preview='_fzf_preview_file {}'
+        set file_paths_selected ($fd_cmd 2>/dev/null | _fzf_wrapper $fzf_arguments)
+    end
+
+
+    if test $status -eq 0
+        commandline --current-token --replace -- (string escape -- $file_paths_selected | string join ' ')
+    end
+
+    commandline --function repaint
+end

dot_config/private_fish/functions/_fzf_search_git_log.fish

@@ -0,0 +1,30 @@
+function _fzf_search_git_log --description "Search the output of git log and preview commits. Replace the current token with the selected commit hash."
+    if not git rev-parse --git-dir >/dev/null 2>&1
+        echo '_fzf_search_git_log: Not in a git repository.' >&2
+    else
+        if not set --query fzf_git_log_format
+            # %h gives you the abbreviated commit hash, which is useful for saving screen space, but we will have to expand it later below
+            set fzf_git_log_format '%C(bold blue)%h%C(reset) - %C(cyan)%ad%C(reset) %C(yellow)%d%C(reset) %C(normal)%s%C(reset)  %C(dim normal)[%an]%C(reset)'
+        end
+        set selected_log_lines (
+            git log --no-show-signature --color=always --format=format:$fzf_git_log_format --date=short | \
+            _fzf_wrapper --ansi \
+                --multi \
+                --tiebreak=index \
+                --prompt="Search Git Log> " \
+                --preview='git show --color=always --stat --patch {1}' \
+                --query=(commandline --current-token) \
+                $fzf_git_log_opts
+        )
+        if test $status -eq 0
+            for line in $selected_log_lines
+                set abbreviated_commit_hash (string split --field 1 " " $line)
+                set full_commit_hash (git rev-parse $abbreviated_commit_hash)
+                set --append commit_hashes $full_commit_hash
+            end
+            commandline --current-token --replace (string join ' ' $commit_hashes)
+        end
+    end
+
+    commandline --function repaint
+end

dot_config/private_fish/functions/_fzf_search_git_status.fish

@@ -0,0 +1,36 @@
+function _fzf_search_git_status --description "Search the output of git status. Replace the current token with the selected file paths."
+    if not git rev-parse --git-dir >/dev/null 2>&1
+        echo '_fzf_search_git_status: Not in a git repository.' >&2
+    else
+        set selected_paths (
+            # Pass configuration color.status=always to force status to use colors even though output is sent to a pipe
+            git -c color.status=always status --short |
+            _fzf_wrapper --ansi \
+                --multi \
+                --prompt="Search Git Status> " \
+                --query=(commandline --current-token) \
+                --preview='_fzf_preview_changed_file {}' \
+                --nth="2.." \
+                $fzf_git_status_opts
+        )
+        if test $status -eq 0
+            # git status --short automatically escapes the paths of most files for us so not going to bother trying to handle
+            # the few edges cases of weird file names that should be extremely rare (e.g. "this;needs;escaping")
+            set cleaned_paths
+
+            for path in $selected_paths
+                if test (string sub --length 1 $path) = R
+                    # path has been renamed and looks like "R LICENSE -> LICENSE.md"
+                    # extract the path to use from after the arrow
+                    set --append cleaned_paths (string split -- "-> " $path)[-1]
+                else
+                    set --append cleaned_paths (string sub --start=4 $path)
+                end
+            end
+
+            commandline --current-token --replace -- (string join ' ' $cleaned_paths)
+        end
+    end
+
+    commandline --function repaint
+end

dot_config/private_fish/functions/_fzf_search_history.fish

@@ -0,0 +1,31 @@
+function _fzf_search_history --description "Search command history. Replace the command line with the selected command."
+    # history merge incorporates history changes from other fish sessions
+    # it errors out if called in private mode
+    if test -z "$fish_private_mode"
+        builtin history merge
+    end
+
+    # Delinate commands throughout pipeline using null rather than newlines because commands can be multi-line
+    set commands_selected (
+        # Reference https://devhints.io/strftime to understand strftime format symbols
+        builtin history --null --show-time="%m-%d %H:%M:%S │ " |
+        _fzf_wrapper --read0 \
+            --print0 \
+            --multi \
+            --tiebreak=index \
+            --prompt="Search History> " \
+            --query=(commandline) \
+            --preview="echo -- {4..} | fish_indent --ansi" \
+            --preview-window="bottom:3:wrap" \
+            $fzf_history_opts |
+        string split0 |
+        # remove timestamps from commands selected
+        string replace --regex '^\d\d-\d\d \d\d:\d\d:\d\d │ ' ''
+    )
+
+    if test $status -eq 0
+        commandline --replace -- $commands_selected
+    end
+
+    commandline --function repaint
+end

dot_config/private_fish/functions/_fzf_search_processes.fish

@@ -0,0 +1,29 @@
+function _fzf_search_processes --description "Search all running processes. Replace the current token with the pid of the selected process."
+    # use all caps to be consistent with ps default format
+    # snake_case because ps doesn't seem to allow spaces in the field names
+    set ps_preview_fmt (string join ',' 'pid' 'ppid=PARENT' 'user' '%cpu' 'rss=RSS_IN_KB' 'start=START_TIME' 'command')
+    set processes_selected (
+        ps -A -opid,command | \
+        _fzf_wrapper --multi \
+                    --prompt="Search Processes> " \
+                    --query (commandline --current-token) \
+                    --ansi \
+                    # first line outputted by ps is a header, so we need to mark it as so
+                    --header-lines=1 \
+                    # ps uses exit code 1 if the process was not found, in which case show an message explaining so
+                    --preview="ps -o '$ps_preview_fmt' -p {1} || echo 'Cannot preview {1} because it exited.'" \
+                    --preview-window="bottom:4:wrap" \
+                    $fzf_processes_opts
+    )
+
+    if test $status -eq 0
+        for process in $processes_selected
+            set --append pids_selected (string split --no-empty --field=1 -- " " $process)
+        end
+
+        # string join to replace the newlines outputted by string split with spaces
+        commandline --current-token --replace -- (string join ' ' $pids_selected)
+    end
+
+    commandline --function repaint
+end

dot_config/private_fish/functions/_fzf_search_variables.fish

@@ -0,0 +1,48 @@
+# This function expects the following two arguments:
+# argument 1 = output of (set --show | psub), i.e. a file with the scope info and values of all variables
+# argument 2 = output of (set --names | psub), i.e. a file with all variable names
+function _fzf_search_variables --argument-names set_show_output set_names_output --description "Search and preview shell variables. Replace the current token with the selected variable."
+    if test -z "$set_names_output"
+        printf '%s\n' '_fzf_search_variables requires 2 arguments.' >&2
+
+        commandline --function repaint
+        return 22 # 22 means invalid argument in POSIX
+    end
+
+    # Exclude the history variable from being piped into fzf because
+    # 1. it's not included in $set_names_output
+    # 2. it tends to be a very large value => increases computation time
+    # 3._fzf_search_history is a much better way to examine history anyway
+    set all_variable_names (string match --invert history <$set_names_output)
+
+    set current_token (commandline --current-token)
+    # Use the current token to pre-populate fzf's query. If the current token begins
+    # with a $, remove it from the query so that it will better match the variable names
+    set cleaned_curr_token (string replace -- '$' '' $current_token)
+
+    set variable_names_selected (
+        printf '%s\n' $all_variable_names |
+        _fzf_wrapper --preview "_fzf_extract_var_info {} $set_show_output" \
+            --prompt="Search Variables> " \
+            --preview-window="wrap" \
+            --multi \
+            --query=$cleaned_curr_token \
+            # $fzf_shell_vars_opts is the deprecated version of $fzf_variables_opts
+            $fzf_shell_vars_opts $fzf_variables_opts
+    )
+
+    if test $status -eq 0
+        # If the current token begins with a $, do not overwrite the $ when
+        # replacing the current token with the selected variable.
+        # Uses brace expansion to prepend $ to each variable name.
+        commandline --current-token --replace (
+            if string match --quiet -- '$*' $current_token
+                string join " " \${$variable_names_selected}
+            else
+                string join " " $variable_names_selected
+            end
+        )
+    end
+
+    commandline --function repaint
+end

dot_config/private_fish/functions/_fzf_wrapper.fish

@@ -0,0 +1,20 @@
+function _fzf_wrapper --description "Prepares some environment variables before executing fzf."
+    # Make sure fzf uses fish to execute preview commands, some of which
+    # are autoloaded fish functions so don't exist in other shells.
+    # Use --local so that it doesn't clobber SHELL outside of this function.
+    set --local --export SHELL (command --search fish)
+
+    # If FZF_DEFAULT_OPTS is not set, then set some sane defaults.
+    # See https://github.com/junegunn/fzf#environment-variables
+    if not set --query FZF_DEFAULT_OPTS
+        # cycle allows jumping between the first and last results, making scrolling faster
+        # layout=reverse lists results top to bottom, mimicking the familiar layouts of git log, history, and env
+        # border shows where the fzf window begins and ends
+        # height=90% leaves space to see the current command and some scrollback, maintaining context of work
+        # preview-window=wrap wraps long lines in the preview window, making reading easier
+        # marker=* makes the multi-select marker more distinguishable from the pointer (since both default to >)
+        set --export FZF_DEFAULT_OPTS '--cycle --layout=reverse --border --height=90% --preview-window=wrap --marker="*"'
+    end
+
+    fzf $argv
+end

dot_config/private_fish/functions/bass.fish

@@ -0,0 +1,29 @@
+function bass
+  set -l bash_args $argv
+  set -l bass_debug
+  if test "$bash_args[1]_" = '-d_'
+    set bass_debug true
+    set -e bash_args[1]
+  end
+
+  set -l script_file (mktemp)
+  if command -v python3 >/dev/null 2>&1
+    command python3 -sS (dirname (status -f))/__bass.py $bash_args 3>$script_file
+  else
+    command python -sS (dirname (status -f))/__bass.py $bash_args 3>$script_file
+  end
+  set -l bass_status $status
+  if test $bass_status -ne 0
+    return $bass_status
+  end
+
+  if test -n "$bass_debug"
+    cat $script_file
+  end
+  source $script_file
+  command rm $script_file
+end
+
+function __bass_usage
+  echo "Usage: bass [-d] <bash-command>"
+end

dot_config/private_fish/functions/fish_user_key_bindings.fish

@@ -0,0 +1,3 @@
+function fish_user_key_bindings
+	fzf_key_bindings
+end

dot_config/private_fish/functions/fzf_configure_bindings.fish

@@ -0,0 +1,46 @@
+# Always installs bindings for insert and default mode for simplicity and b/c it has almost no side-effect
+# https://gitter.im/fish-shell/fish-shell?at=60a55915ee77a74d685fa6b1
+function fzf_configure_bindings --description "Installs the default key bindings for fzf.fish with user overrides passed as options."
+    # no need to install bindings if not in interactive mode or running tests
+    status is-interactive || test "$CI" = true; or return
+
+    set options_spec h/help 'directory=?' 'git_log=?' 'git_status=?' 'history=?' 'processes=?' 'variables=?'
+    argparse --max-args=0 --ignore-unknown $options_spec -- $argv 2>/dev/null
+    if test $status -ne 0
+        echo "Invalid option or a positional argument was provided." >&2
+        _fzf_configure_bindings_help
+        return 22
+    else if set --query _flag_help
+        _fzf_configure_bindings_help
+        return
+    else
+        # Initialize with default key sequences and then override or disable them based on flags
+        # index 1 = directory, 2 = git_log, 3 = git_status, 4 = history, 5 = processes, 6 = variables
+        set key_sequences \e\cf \e\cl \e\cs \cr \e\cp \cv # \c = control, \e = escape
+        set --query _flag_directory && set key_sequences[1] "$_flag_directory"
+        set --query _flag_git_log && set key_sequences[2] "$_flag_git_log"
+        set --query _flag_git_status && set key_sequences[3] "$_flag_git_status"
+        set --query _flag_history && set key_sequences[4] "$_flag_history"
+        set --query _flag_processes && set key_sequences[5] "$_flag_processes"
+        set --query _flag_variables && set key_sequences[6] "$_flag_variables"
+
+        # If fzf bindings already exists, uninstall it first for a clean slate
+        if functions --query _fzf_uninstall_bindings
+            _fzf_uninstall_bindings
+        end
+
+        for mode in default insert
+            test -n $key_sequences[1] && bind --mode $mode $key_sequences[1] _fzf_search_directory
+            test -n $key_sequences[2] && bind --mode $mode $key_sequences[2] _fzf_search_git_log
+            test -n $key_sequences[3] && bind --mode $mode $key_sequences[3] _fzf_search_git_status
+            test -n $key_sequences[4] && bind --mode $mode $key_sequences[4] _fzf_search_history
+            test -n $key_sequences[5] && bind --mode $mode $key_sequences[5] _fzf_search_processes
+            test -n $key_sequences[6] && bind --mode $mode $key_sequences[6] "$_fzf_search_vars_command"
+        end
+
+        function _fzf_uninstall_bindings --inherit-variable key_sequences
+            bind --erase -- $key_sequences
+            bind --erase --mode insert -- $key_sequences
+        end
+    end
+end

dot_config/private_fish/functions/man.fish

@@ -0,0 +1,41 @@
+function man --wraps man --description 'Format and display manual pages'
+    set -q man_blink; and set -l blink (set_color $man_blink); or set -l blink (set_color -o red)
+    set -q man_bold; and set -l bold (set_color $man_bold); or set -l bold (set_color -o 5fafd7)
+    set -q man_standout; and set -l standout (set_color $man_standout); or set -l standout (set_color 949494)
+    set -q man_underline; and set -l underline (set_color $man_underline); or set -l underline (set_color -u afafd7)
+
+    set -l end (printf "\e[0m")
+
+    set -lx LESS_TERMCAP_mb $blink
+    set -lx LESS_TERMCAP_md $bold
+    set -lx LESS_TERMCAP_me $end
+    set -lx LESS_TERMCAP_so $standout
+    set -lx LESS_TERMCAP_se $end
+    set -lx LESS_TERMCAP_us $underline
+    set -lx LESS_TERMCAP_ue $end
+    set -lx LESS '-R -s'
+
+    set -lx GROFF_NO_SGR yes # fedora
+
+    set -lx MANPATH (string join : $MANPATH)
+    if test -z "$MANPATH"
+        type -q manpath
+        and set MANPATH (command manpath)
+    end
+
+    # Check data dir for Fish 2.x compatibility
+    set -l fish_data_dir
+    if set -q __fish_data_dir
+        set fish_data_dir $__fish_data_dir
+    else
+        set fish_data_dir $__fish_datadir
+    end
+
+    set -l fish_manpath (dirname $fish_data_dir)/fish/man
+    if test -d "$fish_manpath" -a -n "$MANPATH"
+        set MANPATH "$fish_manpath":$MANPATH
+        command man $argv
+        return
+    end
+    command man $argv
+end

dot_config/private_fish/functions/n.fish

@@ -0,0 +1,36 @@
+# Rename this file to match the name of the function
+# e.g. ~/.config/fish/functions/n.fish
+# or, add the lines to the 'config.fish' file.
+
+function n --wraps nnn --description 'support nnn quit and change directory'
+    # Block nesting of nnn in subshells
+    if test -n "$NNNLVL" -a "$NNNLVL" -ge 1
+        echo "nnn is already running"
+        return
+    end
+
+    # The behaviour is set to cd on quit (nnn checks if NNN_TMPFILE is set)
+    # If NNN_TMPFILE is set to a custom path, it must be exported for nnn to
+    # see. To cd on quit only on ^G, remove the "-x" from both lines below,
+    # without changing the paths.
+    if test -n "$XDG_CONFIG_HOME"
+        set -x NNN_TMPFILE "$XDG_CONFIG_HOME/nnn/.lastd"
+    else
+        set -x NNN_TMPFILE "$HOME/.config/nnn/.lastd"
+    end
+
+    # Unmask ^Q (, ^V etc.) (if required, see `stty -a`) to Quit nnn
+    # stty start undef
+    # stty stop undef
+    # stty lwrap undef
+    # stty lnext undef
+
+    # The command function allows one to alias this function to `nnn` without
+    # making an infinitely recursive alias
+    command nnn $argv
+
+    if test -e $NNN_TMPFILE
+        source $NNN_TMPFILE
+        rm $NNN_TMPFILE
+    end
+end

dot_config/private_fish/functions/nvm.fish

@@ -0,0 +1,53 @@
+function nvm-fast
+	set -q NVM_DIR ; or set -l NVM_DIR ~/.nvm
+	set -l brigand_nvm_fish_path $NVM_DIR/versions/node
+	if test (count $argv[1]) -lt 1
+		echo 'nvm-fast: at least one argument is required'
+	end
+
+	set -l command $argv[1]
+	if test $command = 'use'
+		set target_version "unknown"
+		if test (count $argv) -eq 1
+			if test -f .nvmrc
+				set target_version (cat .nvmrc)
+			else
+				echo "Error: No version provided and no .nvmrc found"
+				return
+			end
+		else
+			set target_version $argv[2]
+		end
+		set -l target_version $target_version
+
+		set -l matched_version (bash -c "source $NVM_DIR/nvm.sh --no-use; nvm_version $target_version")
+
+		if test -z $matched_version -o $matched_version = 'N/A'
+			echo "No version installed for $target_version, run nvm install $target_version"
+			echo "Installed versions: "
+			for file in $brigand_nvm_fish_path/v*
+				echo ' -' $file
+			end
+		else
+			set -l new_path (string match -ev "$brigand_nvm_fish_path" $PATH)
+			if test $matched_version != 'system'
+				set new_path $brigand_nvm_fish_path/$matched_version/bin $new_path
+			end
+			set -gx PATH $new_path
+			set -gx NVM_BIN (which node)
+		end
+	else
+		bash -c "source $NVM_DIR/nvm.sh --no-use; nvm $argv"
+		set -gx NVM_BIN (which node)
+	end
+end
+
+function nvm
+	switch "$FISH_VERSION"
+		case 2.0.0 2.1.0 2.1.1 2.1.2 2.2.0 2.2b1 2.3.0 2.3.1 2.3b1 2.3b2 2.4.0 2.4b1 2.5.0 2.5b1
+			echo "You need fish 2.6.0 or higher to use fast-nvm-fish." 1>&2
+			return 1
+	end
+	nvm-fast $argv
+end
+

dot_config/private_fish/functions/su.fish

@@ -0,0 +1,3 @@
+function su
+   command su --shell=/usr/bin/fish $argv
+end

dot_config/private_fish/functions/symlink_fish_prompt.fish

@@ -0,0 +1 @@
+/home/eric/.local/share/omf/themes/boxfish/fish_prompt.fish

dot_config/private_fish/functions/symlink_fish_prompt.old.fish

@@ -0,0 +1 @@
+/home/eric/.local/share/omf/themes/boxfish/fish_prompt.fish

dot_config/private_fish/functions/symlink_triton.fish

@@ -0,0 +1 @@
+/home/eric/.config/fish/triton/github.com/dukejones/triton/functions/triton.fish